@prog npose.MUF
1 99999 d
1 i
( New pose..
      Quotes are closed. 
      Trailing ?! not in quotes with no trailing space become . o { ?! }
      Unless ?!* is !*, when it's left.
)
: main ( s -- )
  dup not if 
    "Pose][ by Warwick on FurryMuck, (c) 26/8/95 (#" 
      prog int intostr strcat ")" strcat .tell
    " Quotes are auto-closed, trailing !? become . o ( !? )" .tell
    exit 
  then
  me @ "_prefs/pose/quoteclose" getprop if
    dup "\"" instr dup not if pop else
      over swap strcut 1 2 put
      begin
        dup "\"" instr dup not if pop pop break then
        strcut swap pop 1 rot - swap
      repeat
      if "\"" strcat then
    then
  then
  me @ "_prefs/pose/thinks" getprop if
    dup strlen 1 - over over strcut "!?" swap instr not if pop pop else
      begin
        swap 1 - dup 0 < if swap break then
        swap over strcut "!?" swap instr not if break then
      repeat
      pop 1 + strcut
      over not over "?" instr or if
        over dup strlen 1 - dup 0 < if pop 0 then strcut
        swap pop " " strcmp if " . o ( " else ". o ( " then
        swap strcat strcat " )"
      then
      strcat
    then
  then
  dup 1 strcut pop
  me @ "_prefs/pose/punct" getprop dup not if pop "' " then
  swap instr not if " " swap strcat then
  "me" match name swap strcat loc @ 0 rot notify_exclude
;
42 lines displayed.
.
c
q
@register #me npose.MUF=tmp/prog1
@set $tmp/prog1=L
@set $tmp/prog1=3
@propset $tmp/prog1=str:/_/de:A scroll containing a spell called npose.MUF